home *** CD-ROM | disk | FTP | other *** search
/ HamCall (October 1991) / HamCall (Whitehall Publishing)(1991).bin / bcast / bcstcble / insat.bas < prev    next >
BASIC Source File  |  1990-10-14  |  5KB  |  112 lines
  1. 11 '*    INTELSAT/BAS   Vers S1.0    8/27/84
  2. 12 '*    Sanyo BASIC conversion by Wayne Day
  3. 13 '*  This program is in the public domain, and may not be sold
  4. 14 '*
  5. 15 '*  This program calculates the aiming angles from any point in
  6. 16 '*  the northern hemisphere, for selected geostationary satellites.
  7. 17 '*  The satellites included in the data statements are those which
  8. 18 '*  would normally be viewable, and of interest to private
  9. 19 '*  TVRO earth station owners.
  10. 20 '*
  11. 21 '* The magnetic deviation is critical for accurate aiming.  If you
  12. 22 '* do not already know your magnetic deviation, contact the nearest
  13. 23 '* Federal Aviation Agency Flight Service Station, and they should
  14. 24 '* be able to give it to you quickly.
  15. 25 '*
  16. 26 '*
  17. 100 CLS
  18. 110 LOCATE 9 ,1
  19. 120 SYMBOL (90,20),"INTELSAT/BAS",4,4,2
  20. 130 PRINT"                     Satellite Aiming Chart"
  21. 140 PRINT
  22. 150 LINE INPUT"Location name: ";A$
  23. 160 INPUT"Magnetic Deviation";MD
  24. 170 PRINT
  25. 180 PRINT" Do you wish to input location data as decimal Degrees (i.e. 32.00)"
  26. 190 PRINT"  or as Degrees / Minutes / Seconds (i.e. 32 00' 00' ')"
  27. 200 PRINT"      (D)=Decimal      (M)=Minutes/Seconds"
  28. 210 AN$=INKEY$:IF AN$=""THEN 210
  29. 220 IF AN$="D" OR AN$="d" THEN 250
  30. 230 IF AN$="M" OR AN$="m" THEN 280
  31. 240 GOTO 210
  32. 250 PRINT:INPUT "  Latitude: ";LT:LA=LT:LT=LT*.01745
  33. 260 PRINT:INPUT " Longitude: ";LN
  34. 270 GOTO 400
  35. 280 PRINT:INPUT "  Latitude Degrees :";DG
  36. 290 INPUT "           Minutes :";MN
  37. 300 IF MN<0 OR MN>59 THEN BEEP:GOTO 290
  38. 310 INPUT "           Seconds :";SC
  39. 320 IF SC<0 OR SC>59 THEN BEEP:GOTO 310
  40. 330 LT=DG+(MN/60)+(SC/6000):LA=LT:LT=LT*.01745
  41. 340 PRINT:INPUT " Longitude Degrees:";DG
  42. 350 INPUT "           Minutes:";MN
  43. 360 IF MN<0 OR MN>59 THEN BEEP:GOTO 350
  44. 370 INPUT "           Seconds:";SC
  45. 380 IF SC<0 OR SC>59 THEN BEEP:GOTO 370
  46. 390 LN=DG+(MN/60)+(SC/6000)
  47. 400 PRINT:PRINT" Ouput to [S]creen    or    Screen and [P]rinter ?";
  48. 410 AN$=INKEY$: IF AN$="" THEN 410
  49. 420 IF AN$="P" OR AN$="p" THEN LP=1 ELSE LP=0
  50. 430 CLS:PRINT"              Satellite Aiming Chart for "A$
  51. 440 PRINT TAB(15)"Latitude: ";:PRINT USING "###.##";LA;:PRINT " Longitude: ";:PRINT USING "###.##";LN
  52. 450 PRINT STRING$(70,"-")
  53. 460 PRINT"Satellite"TAB(15)"Assigned" TAB(30)"Azimuth" TAB(45) "Azimuth" TAB(60) "Elevation"
  54. 470 PRINT TAB(16)"Orbit" TAB(31) "True" TAB(45)"Magnetic"
  55. 480 PRINT STRING$(70,"-")
  56. 490 IF LP=1 THEN GOSUB 720
  57. 500 RESTORE
  58. 510 READ P,S$: IF P=999 THEN 520 ELSE 560
  59. 520 PRINT"  Press <SPACE BAR> to END, any other key for another";
  60. 530 AN$=INKEY$:IF AN$="" THEN 530
  61. 540 IF AN$=" " THEN 550 ELSE CLS:IF LP=1 THEN LPRINT CHR$(12):GOTO 150
  62. 550 IF LP=1 THEN LPRINT CHR$(12):CLS:END ELSE CLS:END
  63. 560 L=LN-P:C1=L:L=L*.01745
  64. 570 F=COS(L)*COS(LT)
  65. 580 AZ=-ATN(F/SQR(-F*F+1))+3.1415/2
  66. 590 A1=(SIN(1.5705-AZ)-.1513)/COS(1.5705-AZ)
  67. 600 E=ATN(A1)
  68. 610 G=-(TAN(LT)/TAN(AZ)):E=E*57.3
  69. 620 C=-ATN(G/SQR(-G*G+1))+3.1415/2:C=C*57.3
  70. 630 IF C1<0 THEN C=360-C
  71. 640 AM=C-MD
  72. 650 PRINT S$;
  73. 660 PRINT TAB(17);:PRINT USING"###.#";P;
  74. 665 IF E<=0 THEN PRINT "      ***  Satellite Not Visible at this location     ***":GOTO 700
  75. 670 PRINT TAB(31);:PRINT USING"###.#";C;
  76. 680 PRINT TAB(46);:PRINT USING"###.#";AM;
  77. 690 PRINT TAB(62);:PRINT USING"###.#";E
  78. 700 IF LP=1 THEN GOSUB 800
  79. 710 GOTO 510
  80. 720 LPRINT TAB(15)"Satellite Aiming Chart for ";A$
  81. 730 LPRINT TAB(15)"Latitude ";:LPRINT USING "###.##";LA;:
  82. 740 LPRINT " Longitude ";:LPRINT USING "###.##";LN
  83. 750 LPRINT STRING$ (70,"-")
  84. 760 LPRINT "Satellite" TAB(15) "Assigned" TAB(30) "Azimuth" TAB(45) "Azimuth" TAB(60) "Elevation"
  85. 770 LPRINT TAB(16) "Orbit" TAB(31) "True" TAB(45) "Magnetic"
  86. 780 LPRINT STRING$(70,"-")
  87. 790 RETURN
  88. 800 LPRINT S$;
  89. 810 LPRINT TAB(17);:LPRINT USING "###.#";P;
  90. 815 IF E<=0 THEN LPRINT"    *** Satellite Not Visible at this Location ***":GOTO 850
  91. 820 LPRINT TAB(31);:LPRINT USING "###.#";C;
  92. 830 LPRINT TAB(46);:LPRINT USING "###.#";AM;
  93. 840 LPRINT TAB(62);:LPRINT USING "##.#";E
  94. 850 RETURN
  95. 860 DATA 350,ECS1,347,ECS2,338.3,GORIZONT 3,327,RADUGA I1
  96. 870 DATA 325,RADUGA 9,314,RADUGA 6,307,GORIZONT 5
  97. 880 DATA 383,INTELSAT V-F1,300,INTELSAT V-F7,298,INTELSAT V-F5
  98. 890 DATA 283,PALAPA A02,278,PALAPA A01,275,RADUGA 10
  99. 900 DATA 275,GORIZONT 6,270,GORIZONT 2,266,INSAT 1B
  100. 910 DATA 252,PALAPA B01,247,PALAPA B02,242,PALAPA B03
  101. 920 DATA 231,SAKURA CS2A,226,SAKURA CS2B,187,INTELSAT 4A-F6
  102. 930 DATA 34.5,INTELSAT V-F2,31,INTELSAT 4A-F1,27.4,INTELSAT V-F2/F3
  103. 940 DATA 18.5,INTELSAT V-F6,14.5,GORIZONT 4,14,GORIZONT 7
  104. 950 DATA 11.45,SYMPHONIE 1,11.33,SYMPHONIE 2,1.0,INTELSAT 4-F8/F4
  105. 960 DATA 999,END
  106. 970 'ELSAT V-F6,14.5,GORIZONT
  107. 990' FROM TBS BBS BY PERMISSION
  108. 995' 404/320-6202
  109. 997' BILL TONNESON SYSOP
  110.  
  111.  
  112.